选股公式编写样例

　　选股公式，是通过对K线的组成要素(开盘价，收盘价，最高价，最低价，成交量，成交额)进行运算，通过本系统自编公式选股，快速选出我们期望的个股；。我们在编辑器中选择插入函数，可以看到很多供参考的函数列表。

我们可以通过下面的几个常用的例子来进一步了解如何编写选股公式:
例一：
一根K线有四个价格组成：
最高价：HIGH
收盘价：CLOSE
最低价：LOW
开盘价：OPEN
成交量：VOL
成交额：AMO
例二：
两条均线不断地交叉, 就专门设定了一条函数来描述两条线交叉：CROSS(X,Y)
假如下图中的两条均线一条名叫X, 另外一条叫Y
CROSS(X,Y) 表示X向上穿过了Y
CROSS(Y,X) 表示Y向上穿过了X
例三：
前面的CLOSE, 还是VOL, 都表示当天, 或者您使用的不是日线, 那就表示本周期的数据, 那么前几天的怎么表示呢？
REF(X,M)
例如：
REF(CLOSE,5)表示5天前的收盘；
REF(VOL,10)表示10天前的成交量；
这里的M就是参数
如果我想把两个条件并列在一起怎么办？
AND
X AND Y 就表示条件X和条件Y
以上就是我对如何编写选股公式的回答, 希望对您有多帮助。

写条件选股公式时常用的通式

编写条件选股公式时常用的通式。

一、放量、缩量(成交量函数为VOL)

1、放量：
(1).今天成交量较昨天增加了1倍, 表示如下：

　 VOL>REF(VOL,1)*2;

(2).今天成交量较10个交易日平均成交量放大了1倍, 表示如下：

 A:=MA(VOL,10);
 VOL>A*2;

或者直接用如下公式表示：

 VOL>MA(VOL,10)*2;

(3).今日的5日均量较10个交易日平均成交量放大了1倍, 表示如下：

 A:=MA(VOL,10);
 B:=MA(VOL,5);
 B>2*A;

(4).今日的成交量超过了整个流通盘的5％, 表示如下：

　　 VOL*100/CAPITAL>0.05;

其中CAPITAL代表流通盘。
2、缩量
　 (1).今日成交量较昨日减少了一半, 表示如下：

 VOL<0.5*REF(VOL,1);

(2).今日成交量较10个交易日平均成交量减少一倍, 表示如下：

　A:=MA(VOL,10);
　VOL<2*A;

或者直接用如下公式表示：

　VOL<2*MA(VOL,10);

(3).今日的5日均量较10个交易日平均成交量减少1倍, 表示如下：

 A:=MA(VOL,10);
 B:=REF(A,5);
 A<2*B;

(4).今日的成交量低于了整个流通盘的5％, 表示如下：

 VOL*100<0.05*CAPITAL;

二、上涨、下跌
上涨：
今天的涨幅达到5％以上, 表示如下：

CLOSE/REF(CLOSE,1)>1.05;

5日均价向上, 表示如下：

A:=MA(CLOSE,5);
B:=REF(A,1);
B>A;

下跌：
今天的跌幅达到5％以上, 表示如下：

CLOSE/REF(CLOSE,1)<0.95;

5日均价向下, 表示如下：

A:=MA(CLOSE,5);
B:=REF(A,1);
A<B;

(3)、K线的描述

CLOSE>OPEN;

阳线

CLOSE<OPEN;

阴线

OPEN>REF(CLOSE,1);

高开

OPEN<REF(CLOSE,1);

低开

OPEN>REF(HIGH,1);

跳空高开(HIGH为最高价)

OPEN<REF(LOW,1);

跳空低开(LOW为最低价)
三、走势特征选股公式的编制
(1)、N日内创新高

　N:=10;
　HHV(HIGH,N)=HHV(HIGH,0) AND BARSCOUNT(C)>=N;

注：N为指标参数, 可在参数设定范围内设定参数范围。HHV(X,N), 求N周期内X最高值, N=0则从第一个有效值开始；BARSCOUNT(X),将当前位置到N周期前的数值设为1, 若X非0, 则将当前位置到N周期前的数值设为1。
(2)、N日内创新低

　N:=10;
 LLV(LOW,N)=LLV(LOW,0) AND BARSCOUNT(CLOSE)>=N;

注N为指标参数, 可在参数设定范围内设定参数范围。LLV(X,N), 求N周期内X最低值, N=0则从第一个有效值开始；BARSCOUNT(X)第一个有效数据到当前的天数, 例如, BARSCOUNT(CLOSE)以于日线数据取得上市以来总交易日数。
(3)、N日内阴线多于阳线

　N:=10;
 COUNT(OPEN>CLOSE,N)/N<0.5;

注：N为指标参数, 可在参数设定范围内设定参数范围。同时可以自由编辑里面的数值(如0.5等　, 达到确定阴线占全部K线个数的比例)。
(4)、N日内阳线多于阴线

　N:=10;
　COUNT(OPEN<CLOSE,N)/N>0.5;

注：N为指标参数, 可在参数设定范围内设定参数范围。同时可以自由编辑里面的数值(如0.5等　, 达到确定阳线占全部K线个数的比例)。
(5)、N日内上涨多于下跌(第二天开盘高于前一天收盘)

　N:=10;
 COUNT(C>REF(C,1),N)/N>0.5;

注：N为指标参数, 可在参数设定范围内设定参数范围。同时可以自由编辑里面的数值(如0.5等　, 达到确定其中比例)。
(6)、N日内上涨少于下跌(第二天开盘低于前一天收盘)

　N:=10;
　　 COUNT(C>REF(C,1),N)/N<0.5;

注：N为指标参数, 可在参数设定范围内设定参数范围。同时可以自由编辑里面的数值(如0.5等, 达到确定其中比例)。
(7)、连续N日收阳线

　N:=10;
　UP:=CLOSE>OPEN;

 COUNT(UP,N)=N;

注：COUNT(X,N),统计N周期中满足X条件的周期数, 若N=0则从第一个有效值开始。N为指标参数, 可在参数设定范围内设定参数范围。
(8)、连续N日内收阴线

　N:=10;
　UP:=CLOSE<OPEN;
 COUNT(UP,N)=N;

注：COUNT(X,N),统计N周期中满足X条件的周期数, 若N=0则从第一个有效值开始。N为指标参数, 可在参数设定范围内设定参数范围。
(9)、连续N天上涨

　N:=10;
　　　COUNT(CLOSE>REF(CLOSE,1),N)=N;

注：COUNT(X,N),统计N周期中满足X条件的周期数, 若N=0则从第一个有效值开始。N为指标参数, 可在参数设定范围内设定参数范围。
(10)、连续N天下跌

　N:=10;
　　COUNT(C<REF(C,1),N)=N;

注：COUNT(X,N),统计N周期中满足X条件的周期数, 若N=0则从第一个有效值开始。N为指标参数, 可在参数设定范围内设定参数范围。
(11)、首次创新高

　　　BARSSINCE(C>HHV(IF(BARSCOUNT(C)=1,HIGH,0),0))+1=1;

注：BARSCOUNT(X), 若X非0, 则将当前位置到N周期前的数值设为1。
(12)、创历史新高

　　HHV(CLOSE,0)=CLOSE;

注：HHV(X,N), 求N周期内X最高值, N=0则从第一个有效值开始。
(13)、创历史新低

　　LLV(CLOSE,0)=CLOSE;

注：LLV(X,N), 求N周期内X最小值, N=0则从第一个有效值开始。
(14)、单日放量

 N:=2;
 M:=0.04;
 A:=REF(MA(VOL,5),1);
 VOL/A>N AND VOL*100/CAPITAL>M;

注：N为指标参数, 代表今日成交量和前一日的5日均量的比值, 可在参数设定范围内设定参数范围。
(15)、阶段缩量

　　　SUM(VOL*100,N1)/CAPITAL<=N2;

注：N1为要统计的阶段时间, N2为缩量比例, 可在参数设定范围内设定参数范围。
(16)、阶段放量

　　　SUM(VOL*100,N1)/CAPITAL>=N2;

注：N1为要统计的阶段时间, N2为Y放量比例, 可在参数设定范围内设定参数范围。
(17)、持续放量

　N:=10;
 A:=VOL>REF(VOL,1);
 COUNT(A,N)=N;

注：其中条件A的含义为成交量较上一交易日放大, N为要统计的阶段时间, 可在参数设定范围内设定参数范围。
(18)、持续缩量

　N:=10;
　 A:=VOL<REF(VOL,1);
 COUNT(A,N)=N;

注：其中条件A的含义为成交量较上一交易日缩小, N为要统计的阶段时间, 可在参数设定范围内设定参数范围。
(19)、间隔放量

　N:=10;
 A:=MA(VOL,5);
 BARSCOUNT(C)>=N AND HHV(A,N)<N1*LLV(A,N) AND COUNT(VOL>N2*A,N)>N3;

注：A.BARSCOUNT(X)第一个有效数据到当前的天数。BARSCOUNT(C)对于日线数据取得上市以来总交易日数。
B.完整含义：N日内五日均量的最大值小于最小值的N1倍, 成交量大于等于五日均量的N2倍的情况发生的次数多于N3次。
(20)、放量上攻

 A:=(C-REF(C,1))/REF(C,1)>=(N/100);
 SUM(VOL*100,N1)/CAPITAL>=(N2/100) AND COUNT(VOL>REF(VOL,1),N3 )=N3 AND COUNT(A,N3)=N3;

完整含义：每日股价涨幅均大于N%, N1日内累计换手率大于N2%, 并且成交量连续在N3日内放大。
(21)、温和放量上攻
　　　股价小幅上扬

A1:=CLOSE/REF(CLOSE,1);
A2:=A1>1 AND A1<1.03;

成交量小幅上扬

　N:=10;
B1:=VOL/REF(VOL,1);
B2:=B1>1 AND B1<2;
C1:=MA(VOL*100,N)/CAPITAL<0.05;
COUNT(A2 AND B2,N)/N>0.6 AND C1;

完整公式为：

　N:=10;
A1:=CLOSE/REF(CLOSE,1);
A2:=A1>1 AND A1<1.03;
B1:=VOL/REF(VOL,1);
B2:=B1>1 AND B1<2;
C1:=MA(VOL*100,N)/CAPITAL<0.05;
COUNT(A2 AND B2,N)/N>0.6 AND C1;

注：公式分为股价小幅上扬和成交量小幅上扬两个部分, 请在指标编写时注意其结构。
(22)、突然放量

　N:=10;
　　　VOL>REF(HHV(VOL,N),1*M;

注：当前成交量高于N个周期中最大成交量的M倍。
(23)、平台整理

　N:=10;
　　　COUNT(CLOSE,0)>N AND (HHV(CLOSE,N)-LLV(CLOSE,N))/LLV(CLOSE,N)<=(N1/100);

注：COUNT(CLOSE,0)>N为平台整理N个周期的设定。(HHV(CLOSE,N)-LLV(CLOSE,N))/LLV(CLOSE,N)<=(N1/100)为平台整理幅度N1%的设定。
(24)、突破长期盘整

　N:=10;
REF(((HHV(H,N)-LLV(L,N))/LLV(L,N))/LLV(L,N)),1)<=(N1/100) AND C>=REF(HHV(H,N),1) AND BARSCOUNT(C)>N;

注：前N日在上下N1%的幅度内整理：REF(((HHV(H,N)-LLV(L,N))/LLV(L,N))/LLV(L,N)),1)<=(N1/100)；
今日突破：C>=REF(HHV(H,N),1)。
(25)、阶段强势股

 A:=SUM(IF(DATE-N=0,INDEXC,0),0);
 B:=SUM(IF(DATE-N1=0,INDEXC,0)0);
 E:=SUM(IF(DATE-N=0,C,0),0);
 F:=SUM(IF(DATE-N1=0,C,0),0);
 ((F-E)/E)>((B-A)/A);

注：该公式求的是N日-N1日之间涨幅高于大盘的股票。N、N1参数的表达格式为YYMMDD, 注意在2000年前的表达为年份的后两位, 例如1999年为99, 从2000年开始以100依次向后累加, 例如2001年9月14日为1010914, INDEXC函数表示同期大盘的收盘价, 该函数对分笔成交分析周期无效。
(26)、阶段弱势股

 A:=SUM(IF(DATE=N,INDEXC,0),0);
 B:=SUM(IF(DATE=N1,INDEXC,0)0);
 E:=SUM(IF(DATE=N,C,0),0);
 F:=SUM(IF(DATE=N1,C,0),0);
 ((F-E)/E)<((B-A)/A);

注：该公式求的是N日-N1日之间涨幅低于大盘的股票。N、N1参数的表达格式为YYMMDD, 注意在2000年前的表达为年份的后两位, 例如1999年为99, 从2000年开始以100依次向后累加, 例如2001年9月14日为1010914, INDEXC函数表示同期大盘的收盘价, 该函数对分笔成交分析周期无效。
(27)、大盘同步

　　　COUNT((C>O AND INDEXC>INDEXO) OR (C<O AND INDEXC<INDEXO),N)/N>M/100;

注：含义为N周期中与大盘走势相同(同收阴线或同收阳线)的例超过M%。此处的O不是数字的零, 而是开盘价OPEN的首写字母O。
(28)、N日内强势股

　N:=10;
 A:=(C-REF(O,N))/REF(O,N);
 B:=(INDEXC-REF(INDEXO,N))/REF(INDEXO,N);
 A>B AND A/B>=M;

注：N日内个股涨幅大于等于大盘涨幅的M倍。
四、形态特征选股公式的编制
(1)、均线多头排列

 A1:=MA(C,N1);
 A2:=MA(C,N2);
 A3:=MA(C,N3);
 A4:=MA(C,N4);
 EVERY(A1>A2 AND A2>A3 AND A3>A4,3);

注：N1、N2、N3、N4日均线呈多头排列。
(2)、均线空头排列

 A1:=MA(C,N1);
 A2:=MA(C,N2);
 A3:=MA(C,N3);
 A4:=MA(C,N4);
 EVERY(A1<A2 AND A2<A3 AND A3<A4,3);

注：N1、N2、N3、N4日均线呈空头排列。
(3)、早晨之星

　　　REF(CLOSE,2)/REF(OPEN,2<0.95 AND REF(OPEN,1)<REF(CLOSE,2) AND ABS(REF(OPEN,1)-REF(CLOSE,1)/REF(CLOSE,1)<0.03 AND CLOSE/OPEN>1.05 AND CLOSE>REF(CLOSE,2);

注：早晨之星, 这种形态和叫法自然是后市向好, 为买进信号。早晨之星由三根K线组成, 其顺序是：第一天在下跌过程中已形成一根阴线：

　　　REF(CLOSE,2)/REF(OPEN,2<0.95;

第二天呈裂口下跌, K线实体较短, 构成星的主体部分, 阴线或阳线均可, 有无上下影线均不重要。

　　　REF(OPEN,1)<REF(CLOSE,2) AND ABS(REF(OPEN,1)-REF(CLOSE,1)/REF(CLOSE,1)<0.03;

　　　关键是第三根K线必须是阳线, 且其长度至少要升至第一根阴线实体(如果能够“包容”第一根阴线则最好不过了)

　　　CLOSE/OPEN>1.05 AND CLOSE>REF(CLOSE,2);

(4)、强势整理

 M:=10;
 A1:=ABS(CLOSE-OPEN)/OPEN<0.015;
 A2:=EVERY(A,M);
 A3:=REF(O,M)<REF(C,M) AND REF(C,M)/REF(C,M+1)>1+N/100;
 A2 AND A3;

注：一根实体超过N的长阳, 后面跟M个K线实体不超过1.5％的K线。
(5)、高开大阴线

　　　OPEN>CLOSE AND OPEN/REF(C,1)>=1+M/100 AND CLOSE/OPEN<=1-N/100;

注：跳空高开M%, 当日股价较开盘价跌幅大于N。股价经过一段持续攀升之后, 某一日突然跳高开盘：

　　　OPEN/REF(C,1)>=1+M/100;

　　　后股价一路下行, 尾市以接近最低点收市：

　　　CLOSE/OPEN<=1-N/100;

　　　此信号出现, 往往意味着股价已形成短期头部, 应注意回避风险。
(6)、低开大阳线

　　　OPEN<CLOSE AND OPEN/REF(C,1)<=1-M/100 AND CLOSE/OPEN>=1+N/100;

注：跳空低开M%, 当日股价较开盘价涨幅大于N, 其他描述请参见(5)。
(7)、黄昏之星

　　　REF(CLOSE,2)/REF(OPEN,2)>1.03 AND REF(OPEN,1)>REF(CLOSE,2) AND ABS(REF(OPEN,1)-REF(CLOSE,1)/REF(CLOSE,1)<0.02 AND CLOSE/OPEN<0.97 AND CLOSE<REF(CLOSE,2);

注：黄昏之星表示股价回落, 是卖出信号, 应伺机抛货。幕星同样由三根K线组成, 其形态和晨星正好相反：
　　　第一天股价继续上升, 拉出一根阳线：

　　　REF(CLOSE,2)/REF(OPEN,2)>1.03

　　　第二天波动较小, 形成一根小阳线或小阴线, 构成星的主体部分：

　　　REF(OPEN,1)>REF(CLOSE,2) AND ABS(REF(OPEN,1)-REF(CLOSE,1)/REF(CLOSE,1)<0.02;

　　　第三天形成一根包容第二天并延伸至第一天阳线实体：

　　　CLOSE/OPEN<0.97 AND CLOSE<REF(CLOSE,2)

(8)、跳空缺口

　　　HIGH<REF(LOW,1) OR LOW>REF(HIGH,1);

注：从内容上看, 分别是向下跳空缺口和向上跳空缺口。
(9)、均线金叉

 A:=MA(C,5);
 B:=MA(C,10);
 CROSS(A,B);

注：前二句是5、10日均线, CROSS是交叉函数, CROSS(A,B)表示5日均线与10日均线金叉。
(10)、均线死叉

 A:=MA(C,5);
 B:=MA(C,10);
 CROSS(B,A);

注：前二句是5、10日均线, CROSS是交叉函数, CROSS(B,A)表示5日均线与10日均线死叉。
(11)、均线粘合

 MA1:=MA(C,5);
 MA2:=MA(C,10);
 MA3:=MA(C,20);
 P1:=ABS(MA1-MA2)+ABS(MA2-MA3);
 P1/C<M/100 AND MA1>REF(MA1,1) AND MA2>REF(MA2,1);

注：前三句是三根均线, P1是第一根均线减第二根均线差的绝对值与第二根均线减第三根均线差的绝对值之和, 最后一句是P1与收盘价的比值小于一定比率M%(一般该比率为2％以下, 同时前二均线今日比昨日上翘。